Public Sub CreateNewDAO_DB(strDBPathName As String, Optional strPWD As String = "", _
                            Optional boolEncrypt As Boolean = False)
'*******************************************
'Name:      CreateNewDAO_DB   (Sub)
'Purpose:   erstellt ein neue DB mittels DAO
'Author:    Tommyk
'Date:      März 02, 2004, 03:52:24
'Inputs:    strDBPathName=Name und Pfad der neuen DB,strPWD=DB-Passwort
'           boolEncrypt=Verschlüsselt Ja/Nein
'Output:
'*******************************************
On Error GoTo ErrHandler
Dim wsp As DAO.Workspace
Dim db As DAO.Database
Set wsp = DBEngine.Workspaces(0)
    If strPWD = "" Then
        Set db = wsp.CreateDatabase(strDBPathName, dbLangGeneral)
    Else
        If boolEncrypt = False Then
            Set db = wsp.CreateDatabase(strDBPathName, dbLangGeneral & ";pwd=" & strPWD)
        Else
            Set db = wsp.CreateDatabase(strDBPathName, dbLangGeneral & ";pwd=" & strPWD, dbEncrypt)
        End If
    End If
Set db = Nothing
Set wsp = Nothing
ExitHere:
    Exit Sub
ErrHandler:
    Dim strErrString As String
    strErrString = "Error Information..." & vbCrLf
    strErrString = strErrString & "Error#: " & Err.Number & vbCrLf
    strErrString = strErrString & "Description: " & Err.Description
    MsgBox strErrString, vbCritical + vbOKOnly, "Error in Sub: CreateNewDAO_DB"
    Resume ExitHere
End Sub